home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib05.dsk
/
LO-RES DUMP.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
1KB
|
56 lines
0 REM ***************
1 REM * LO-RES DUMP *
2 REM * GLENN TEMAN *
3 REM ***************
4 REM
10 GOSUB 1000: REM INIT
15 PRINT : PRINT "LO-RES DUMP....": PRINT
20 PRINT : GOSUB 500
30 FOR Y = 0 TO 39
40 PRINT : PRINT L$;
50 FOR X = 0 TO 39
60 S = SCRN( X,Y)
70 PRINT C$(S);
80 NEXT X
83 PRINT L$;
85 NEXT Y
90 PRINT
100 GOSUB 500
110 PRINT : PRINT
115 GOSUB 200
120 PRINT D$;"PR#0"
130 HOME
140 PRINT CHR$(7);"ALL DONE!"
150 END
200 PRINT
210 FOR I = 1 TO 15
220 X = INT((I/3 - INT(I/3)) *3 +.5)
230 IF X = 0 THEN HTAB 30
240 IF X = 1 THEN PRINT
250 IF X = 2 THEN HTAB 15
255 READ A$
260 PRINT C$(I);" ";A$;
270 NEXT
280 PRINT
290 RETURN
500 PRINT "-----------------------------------------";: REM 41 -'S
510 RETURN
1000 HOME
1010 VTAB 21: HTAB 14: PRINT "LO-RES DUMP"
1020 HTAB 23: PRINT "BY GLENN TEMAN"
1030 FOR X = 1 TO 1500: NEXT X
1040 HOME
1070 INPUT "PRINTER SLOT: ";PS
1080 DIM C$(15)
1090 C$(0) = " "
1100 FOR I = 1 TO 9:C$(I) = STR$(I): NEXT I
1110 DATA A,B,C,D,E,F
1120 FOR I = 10 TO 15: READ C$(I): NEXT
1130 D$ = CHR$(4)
1140 L$ = CHR$(124)
1150 HOME : PRINT "AND AWAY WE GO..."
1160 FOR I = 1 TO 200: NEXT I
1170 PRINT D$;"PR#";PS
1180 RETURN
2000 DATA MAGENTA,DK BLUE,PURPLE,DK GREEN,GREY 1,MED BLUE
2010 DATA LT BLUE,BROWN,ORANGE,GREY 2,PINK,LT GREEN,YELLOW,AQUA,WHITE